terraform-contour-mirror/modules/rabbitmq/outputs.tf

output "vhosts" {
  description = "RabbitMQ vhosts managed by this component."
  value       = keys(rabbitmq_vhost.this)
}

output "users" {
  description = "RabbitMQ users managed by this component."
  value       = sort(concat(keys(rabbitmq_user.this), tolist(var.unmanaged_output_users)))
}

output "rabbitmq_outputs_map" {
  description = "Map for k8s-secret module. Key format: default:vhost:user."
  value = {
    for key, item in merge(local.user_vhosts, {
      for item in var.unmanaged_output_permissions : "${item.vhost}:${item.user}" => {
        vhost = item.vhost
        user  = item.user
      }
      }) : "default:${item.vhost}:${item.user}" => {
      host                = var.amqp_host
      port                = tostring(var.amqp_port)
      vhost               = item.vhost
      username            = try(rabbitmq_user.this[item.user].name, item.user)
      password            = try(random_password.user[item.user].result, "")
      uri                 = try("amqp://${rabbitmq_user.this[item.user].name}:${urlencode(random_password.user[item.user].result)}@${var.amqp_host}:${var.amqp_port}/${urlencode(item.vhost)}", "")
      management_endpoint = var.management_endpoint
    }
  }
  sensitive = true
}